PaglalarawanStationaryStatesAnimation.gif	English: Three wavefunction solutions to the Time-Dependent Schrödinger equation for a harmonic oscillator. Left: The real part (blue) and imaginary part (red) of the wavefunction. Right: The probability of finding the particle at a certain position. The top two rows are the lowest two energy eigenstates, and the bottom is the superposition state ${\displaystyle \psi _{N}=(\psi _{0}+\psi _{1})/{\sqrt {2}}}$, which is not an energy eigenstate. The right column illustrates why energy eigenstates are also called "stationary states". Thus in every quantum stae,there are certain preferred positions of maximum probability
Petsa	20 Marso 2011
Pinanggalingan	Sariling gawa
May-akda	Sbyrnes321

(* Source code written in Mathematica 6.0 by Steve Byrnes, Feb. 2011. This source code is public domain. *)
(* Shows classical and quantum trajectory animations for a harmonic potential. Assume m=w=hbar=1. *)
ClearAll["Global`*"]
(*** Wavefunctions of the energy eigenstates ***)
psi[n_, x_] := (2^n*n!)^(-1/2)*Pi^(-1/4)*Exp[-x^2/2]*HermiteH[n, x];
energy[n_] := n + 1/2;
psit[n_, x_, t_] := psi[n, x] Exp[-I*energy[n]*t];
(*** A non-stationary state ***)
SeedRandom[1];
psinonstationary[x_, t_] := (psit[0, x, t]+psit[1, x, t])/Sqrt[2];

(*** Put all the plots together ***)
SetOptions[Plot, {PlotRange -> {-1, 1}, Ticks -> None, PlotStyle -> {Directive[Thick, Blue], Directive[Thick, Pink]}}];
MakeFrame[t_] := GraphicsGrid[
   {{Plot[{Re[psit[0, x, t]], Im[psit[0, x, t]]}, {x, -5, 5}, PlotLabel -> Subscript[\[Psi],0]], 
     Plot[Abs[psit[0, x, t]]^2, {x, -5, 5}, PlotStyle -> Directive[Thick, Black],
		PlotLabel -> TraditionalForm[Abs[Subscript[\[Psi],0]]^2]]},
   {Plot[{Re[psit[1, x, t]], Im[psit[1, x, t]]}, {x, -5, 5}, PlotLabel -> Subscript[\[Psi],1]], 
     Plot[Abs[psit[1, x, t]]^2, {x, -5, 5}, PlotStyle -> Directive[Thick, Black],
		PlotLabel -> TraditionalForm[Abs[Subscript[\[Psi],1]]^2]]},
   {Plot[{Re[psinonstationary[x, t]], Im[psinonstationary[x, t]]}, {x, -5, 5}, PlotLabel -> Subscript[\[Psi],N]], 
     Plot[Abs[psinonstationary[x, t]]^2, {x, -5, 5}, PlotStyle -> Directive[Thick, Black],
		PlotLabel -> TraditionalForm[Abs[Subscript[\[Psi],N]]^2]]}
   }, Frame -> All, ImageSize -> 300];
output = Table[MakeFrame[t], {t, 0, 4 Pi*40/41, 4 Pi/41}];
SetDirectory["C:\\Users\\Steve\\Desktop"]
Export["test.gif", output]

Ako, na may karapatang-ari ng akdang ito, ang naglalathala nito alinsunod sa ilalim ng sumusunod na mga lisensya:

Ang talaksang ito ay ginawang makukuha sa ilalim ng Dedikasyon ng Pandaigdigang Saklaw ng Madla CC0 1.0 ng Creative Commons.

Ang taong nag-ugnay ng isang akda sa kasulatang ito ay inilaan ang akda sa Commons sa saklaw ng madla na isinusukong pangbuong-mundo ang lahat ng kanyang mga karapatan sa akda sa ilalim ng batas sa karapatang-ari, kasama ang lahat ng kaugnay at karatig na mga karapatan, hanggang sa naaabot ng batas. Maaari mong kopyahin, baguhin, ipamahagi at isagawa ang akda, kahit na para sa mga layunin pangkalakal, lahat-lahat na hindi nangangailangan ng pahintulot. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse